How To Auto Refresh ALV Grid Display Using CL_GUI_TIMER?

report z_auto_refresh.
*&---------------------------------------------------------------------*
*& Lesson : Auto refresh ALV output
*& Level  : ABAP Code Example
*& Tutor  : ABAPGeeks.com
*&---------------------------------------------------------------------*
class cl_alv definition.
  public section.
    data : ob_timer  type ref to cl_gui_timer . "An object of type CL_GUI_TIMER,
                                                "sesponsible for triggering the auto-refresh
                                                "functionality at regular intervals.

    methods:
      get_data, "Retrieves data from the SCARR table into the it_data internal table.
      set_field_cat, "Builds the field catalog (gt_fcat) to define the structure of the ALV grid display.
      display_report, "Initializes the ALV grid and sets it up with data and the field catalog.
      timer_event for event finished of cl_gui_timer. "This is the event handler triggered when the timer interval elapses.
  private section.
    data: grid type ref to cl_gui_alv_grid.
    data: it_data type table of scarr.
    data: ls_layo type lvc_s_layo,
          gt_fcat type lvc_t_fcat,
          gs_fcat type lvc_s_fcat.

endclass.

class cl_alv implementation.
  method timer_event.

    get_data( ). "Fetches the latest data by calling get_data.

    if grid is initial.
      call function 'GET_GLOBALS_FROM_SLVC_FULLSCR'
        importing
          e_grid = grid.
    endif.

    "Refreshes the ALV grid to display updated data using
    "check_changed_data and refresh_table_display.
    call method: grid->check_changed_data,
                 grid->refresh_table_display.

    "Restarts the timer (ob_timer->run) to continue the auto-refresh cycle.
    ob_timer->run( ).

  endmethod.
  method set_field_cat.
"Simplifies the addition of field catalog entries by specifying column position,
"field name, description, and output length.
    define add_fcat.
      clear gs_fcat.
      gs_fcat-col_pos = &1.
      gs_fcat-fieldname = &2.
      gs_fcat-coltext = &3.
      gs_fcat-outputlen = &4.
      append gs_fcat to gt_fcat.
    end-of-definition.

    add_fcat:
       1 'CARRID' 'Carr ID' 5,
       2 'CARRNAME' 'Carrier Name' 20,
       3 'CURRCODE' 'Curr Code.' 5,
       4 'URL' 'Url.' 30.
  endmethod.

  method get_data.
    select * into table it_data from scarr.
  endmethod.
  method display_report.

    "Using this statement, we don't need to create a custom container
    "If you open screen 100, it's just a blank dialog screen without any control
    grid =
      new cl_gui_alv_grid(
          i_parent = cl_gui_container=>default_screen ).

    set_field_cat( ).

    ls_layo-zebra = 'X'.

    call method grid->set_table_for_first_display(
      exporting
        is_layout                     = ls_layo                " Layout
      changing
        it_outtab                     = it_data               " Output Table
        it_fieldcatalog               = gt_fcat               " Field Catalog
      exceptions
        invalid_parameter_combination = 1                " Wrong Parameter
        program_error                 = 2                " Program Errors
        too_many_lines                = 3                " Too many Rows in Ready for Input Grid
        others                        = 4
                                        ).
    if sy-subrc <> 0.
      message id sy-msgid type sy-msgty number sy-msgno
        with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    endif.

    call screen 100. "This is just a blank screen

  endmethod.
endclass.

start-of-selection.
  data: o_alv type ref to cl_alv.
  create object: o_alv, o_alv->ob_timer.
  "Associates the timer_event method with the finished event of the timer object (ob_timer)
  set handler o_alv->timer_event for o_alv->ob_timer.
  o_alv->ob_timer->interval = 3.
  o_alv->ob_timer->run( ).
  o_alv->get_data( ).
  o_alv->display_report( ).
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
module status_0100 output.
  set pf-status 'PF-STATUS'.
*  SET TITLEBAR 'xxx'.
endmodule.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
module user_command_0100 input.
  IF sy-ucomm = 'BACK' or sy-ucomm = 'EXIT' or sy-ucomm = 'CANCEL'.
    SET SCREEN 0.
  ENDIF.
endmodule.